I am unable to set the default font size for the game (in display tab). The number changes, in UI and code, but has no effect on the font.

Am I missing something here? Is there another way to change the font size globally?

Did you ever sort this? I have just checked it it works for me, both desktop and online. Is there something else going on that could affect it?

You can try to manually set it with this code. The Quest Default is size 11 I believe.

ClearScreen
msg ("This is the \"Font Size\" help guide. {once:If you have any further questions feel free to contact me about them and I will be happy to answer anything you like.}<br/><br/>Please type your desired <font color=\"dedede\"><i>Font Size</i></font color> in the command bar. For example, the current default font size is <font color=\"dedede\">11</font color>.")
get input {
  SetFontSize (ToInt(result))
  ClearScreen
  msg ("<br/><font color=\"dedede\">Would you like to change the Inventory/Surroundings/Status Pane text size as well? Do anything else to <i>cancel</i></font color> ")
  menulist = Split("Yes;No;Reset Default", ";")
  ShowMenu ("", menulist, true) {
    if (result = "Yes") {
      regEx = "^\\d(\\d||)(\\d|)px$"
      msg ("<br/>Excellent! Please, provide a new font size (between 11-13px would be a safe bet)! As an example, you type <font color=\"dedede\">12px</font color>. ")
      get input {
        result = LCase(result)
        if (IsRegExMatch(regEx,result)) {
          JS.eval ("setTimeout(function(){$('#gamePanes li').css('font-size','"+result+"');},1);")
          game.paneitemsfontsize = result
          firsttime {
            create turnscript ("paneitemsfontsizeturnscript")
          }
          paneitemsfontsizeturnscript.script => {
            JS.eval ("setTimeout(function(){$('#gamePanes li').css('font-size','"+game.paneitemsfontsize+"');},1);")
          }
          paneitemsfontsizeturnscript.enabled = true
        }
        else {
          msg ("<br/>Something went wrong. Don't forget to enter your number followed by px. Like this: <font color=\"dedede\">12px</font color>. You'll have to reopen the Help Guide.")
        }
      }
    }
    else if (result = "No") {
    }
    else if (result = "Reset Default") {
      ClearScreen
      msg ("<br/>Done!")
      DisableTurnScript (paneitemsfontsizeturnscript)
    }
  }
}